build.gradle


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

plugins {
    id 'java'
    id 'com.github.johnrengelman.shadow' version '7.0.0'
    id 'maven-publish'
}

defaultTasks 'allJar'

allprojects {
    apply plugin: 'java'

    group = 'com.leonardobishop'
    version = '3.0.1'

    sourceCompatibility = 1.8
    targetCompatibility = 1.8
}
task allJar( type: Jar, dependsOn: subprojects.tasks['build'] ) {
    subprojects.each { subproject ->
        from subproject.configurations.archives.allArtifacts.files.collect {
            zipTree(it)
        }
    }
    archiveBaseName = 'Quests'
}

artifacts {
    archives allJar
}

publishing {
    publications {
        maven(MavenPublication) {
            groupId = 'com.leonardobishop'
            artifactId = 'quests'
            version = project.version

            artifact allJar
            pom.withXml {
                asNode().dependencies.dependency.each { dep ->
                    dep.parent().remove(dep)
                }
            }
        }
    }

    repositories {
        maven {
            credentials {
                username = project.findProperty('mavenUser') ?: System.getenv('MAVEN_USER')
                password = project.findProperty('mavenPassword') ?: System.getenv('MAVEN_PASSWORD')
            }
            url = "https://repo.leonardobishop.com/releases/"
        }
    }
}