# Maintainer: Leonardo Bishop <me@leonardobishop.net>
_pkgname=stash
pkgname="${_pkgname}-git"
pkgdesc="Saved articles tracker"
pkgver=r9.1b7c07d
pkgrel=1
makedepends=('go' 'make' 'git')
arch=('x86_64')
url="https://git.leonardobishop.net/stash/about/"
license=('AGPL-3.0-or-later')
conflicts=("${_pkgname}")
provides=("${_pkgname}=${pkgver}")
source=(stash::git+https://git.leonardobishop.net/stash/
  stash.service
  stash.sysusers
  config.yaml
  )
sha256sums=('SKIP'
            'cf9e76a0ff22be285e4e392507310ceba5128f61b973058d9e6b7b5d2e43e50c'
            '2eb21fe51a69bcff17268f476b8e9f059730660cce4eba1325f71dc1393756da'
            'f2f11c1abb5956fb1aa278cb724ff985f033501ed786606c8f85040d74e3007a')
backup=(etc/stash/config.yaml)

pkgver() {
  cd "stash"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

prepare() {
  export GOPATH="$srcdir/build"

  cd "stash"
  go mod download
}

build() {
  export GOPATH="$srcdir/build"
  export PATH="$PATH:$srcdir/build/bin"

  cd "stash"
  make
}

package() {
  install -Dm755 "$srcdir/stash/stash" "$pkgdir/usr/bin/stash"
  install -Dm644 "$srcdir/stash.service" "$pkgdir/usr/lib/systemd/system/stash.service"
  install -Dm644 "$srcdir/stash.sysusers" "$pkgdir/usr/lib/sysusers.d/stash.conf"
  install -Dm755 -d "${pkgdir}/etc/stash"
  install -Dm644 "$srcdir/config.yaml" "$pkgdir/etc/stash/config.yaml"
}