# Maintainer: Leonardo Bishop <me@leonardobishop.net>
_pkgname=walrss
pkgname="${_pkgname}-git"
pkgdesc="Email-based RSS digest generator"
pkgver=0.4.4.r1.g1c542bd
pkgrel=1
makedepends=('go' 'make' 'git')
arch=('x86_64')
url="https://github.com/codemicro/walrss"
license=('AGPL-3.0-only')
conflicts=("${_pkgname}")
provides=("${_pkgname}=${pkgver}")
source=(walrss::git+https://github.com/codemicro/walrss
  walrss.service
  walrss.sysusers
  walrss.conf
  0001-Update-directories-fig-searches.patch
  config.yaml)
sha256sums=('SKIP'
            '8b87e2f23d06e0a81fb747dccbd5d11b971ac298803d3aadfdf2623b4efc269e'
            '662f0df2e8025034d395e15726883bb009af89ec02aa3a198fd40d792a5c4ace'
            'd3fdc459dd3c712da5ec62213ef15d8d5d7ad2335bffbb277fc8eac66fd2cd79'
            '9943f9c4eafa25647f38c20ae5e929f1bbc0d6771cb7f24f135e34bf4fdb52e0'
            '2eeefbed0bb7a4936c020e85ad3fed21cf598fab14900c8149ca9bb87f4516b3')

pkgver() {
  cd "walrss"
  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  export GOPATH="$srcdir/build"

  cd "walrss"
  git apply "$srcdir/0001-Update-directories-fig-searches.patch"
  go mod download
  go install github.com/valyala/quicktemplate/qtc@latest
}

build() {
  export GOPATH="$srcdir/build"
  export PATH="$PATH:$srcdir/build/bin"

  cd "walrss"
  make
}

package() {
  install -Dm755 "$srcdir/walrss/bin/walrss" "$pkgdir/usr/bin/walrss"
  install -Dm644 "$srcdir/walrss.service" "$pkgdir/usr/lib/systemd/system/walrss.service"
  install -Dm644 "$srcdir/walrss.sysusers" "$pkgdir/usr/lib/sysusers.d/walrss.conf"
  install -Dm644 "$srcdir/walrss.conf" "$pkgdir/etc/conf.d/walrss"
  install -Dm755 -d "${pkgdir}/etc/walrss"
  install -Dm644 "$srcdir/config.yaml" "$pkgdir/etc/walrss/config.yaml"
}