blob: 9fb27d9041b22c3e597a5d29c8c5cc746aadc908 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Maintainer: Leonardo Bishop <me@leonardobishop.net>
_pkgname=walrss
pkgname="${_pkgname}-git"
pkgdesc="Email-based RSS digest generator"
pkgver=0.4.4.r1.g1c542bd
pkgrel=6
makedepends=('go' 'make' 'git')
arch=('x86_64')
url="https://github.com/codemicro/walrss"
license=('AGPL-3.0-only')
conflicts=("${_pkgname}")
provides=("${_pkgname}=${pkgver}")
source=(walrss::git+https://github.com/codemicro/walrss
walrss.service
walrss.sysusers
walrss.conf
config.yaml
0001-Update-directories-fig-searches.patch
0002-Set-version-information-at-build.patch
)
sha256sums=('SKIP'
'8b87e2f23d06e0a81fb747dccbd5d11b971ac298803d3aadfdf2623b4efc269e'
'662f0df2e8025034d395e15726883bb009af89ec02aa3a198fd40d792a5c4ace'
'd3fdc459dd3c712da5ec62213ef15d8d5d7ad2335bffbb277fc8eac66fd2cd79'
'2eeefbed0bb7a4936c020e85ad3fed21cf598fab14900c8149ca9bb87f4516b3'
'cd1ef7762f3ad8889d1e52cebccf42d58080ca42bde60f876a1623d34771e7c4'
'188dbd12403db528b5a84df86b38ffe5ad0cb1ed20b7d8ecbfed4501b44c0f36')
backup=(etc/walrss/config.yaml
etc/conf.d/walrss)
pkgver() {
cd "walrss"
git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
export GOPATH="$srcdir/build"
for patch in *.patch
do
patch -p1 -d "walrss" < "$srcdir/$patch"
done
cd "walrss"
go mod download
go install github.com/valyala/quicktemplate/qtc@latest
}
build() {
export GOPATH="$srcdir/build"
export PATH="$PATH:$srcdir/build/bin"
cd "walrss"
make
}
package() {
install -Dm755 "$srcdir/walrss/bin/walrss" "$pkgdir/usr/bin/walrss"
install -Dm644 "$srcdir/walrss.service" "$pkgdir/usr/lib/systemd/system/walrss.service"
install -Dm644 "$srcdir/walrss.sysusers" "$pkgdir/usr/lib/sysusers.d/walrss.conf"
install -Dm644 "$srcdir/walrss.conf" "$pkgdir/etc/conf.d/walrss"
install -Dm755 -d "${pkgdir}/etc/walrss"
install -Dm644 "$srcdir/config.yaml" "$pkgdir/etc/walrss/config.yaml"
}
|
